package
{
	import flash.display.Sprite;
	import frocessing.display.F5MovieClip3D;
	import flash.events.Event;

	[SWF(width="425", height="425", backgroundColor="#000000", frameRate="60")]
	public class Curve3D extends F5MovieClip3D
	{
		private var num:int;
		private var a:Number;
		
		private var i:int;
		private var ss:Number;
		private var vsa:Number;

		public function Curve3D()
		{
			QMedium();
			
			num = 100;
			a = 0;
			
			ss = 100;
			vsa = 0;
			
			curveDetail( 100 );
			colorMode( RGB, num*2 );
			noFill();
			
			perspective( PI/2 );
		}
		
		// this function must be public so the base class can find it as this["draw"] (see F5MovieClip::loop())
		public function draw():void {
				translate( fg.width/2, fg.height/2, -100 + mouseY );
				rotateY( a );
				rotateX( a/3 );
				
				vsa += (mouseX*0.1*PI - vsa)*0.05;
				
				beginShape();
				for( i=0;i<num;i++ ){
					stroke( i + num );
					var vy:Number = ss - ss*2*i/num;
					var vs:Number = cos(vsa*vy/ss);
					var vx:Number = ss*cos(i*0.8)*vs;
					var vz:Number = ss*sin(i*0.8)*vs;
					moveToLast();
					curveVertex3d( vx, vy, vz );
				}
				endShape();
				
				a += 0.01;
		}

	}
}